DIY Simon with Arduino w/ Source and Diagram

 /*
   Simon Sez
 
 
  created Feb 10 2010
  by Alex Britez
 
  http://blog.unthinkmedia.com/?p=475
 
  */
 
#include <Tone.h>
 
Tone audioFeedback;
 
//DEFINE MOTOR
int transistorPin = 12; 
 
int speakerPin = 6; 
 
//DEFINE LEDS
int ledWhite = 11;
int ledGreen = 10;
int ledRed = 9;
int ledYellow = 8;
 
char leds[] = {
  ledWhite,ledGreen,ledRed,ledYellow};
 
//DEFINE SWITCHES 
int switchWhite = 5;
int switchGreen = 4;
int switchRed = 3;
int switchYellow = 2;
 
//AUDIO
int notes[] = {
  NOTE_D4,NOTE_E4,NOTE_F4,NOTE_G4};
//this plays if you win
int winNotes[] = {
  NOTE_D4, NOTE_E4,NOTE_C4,NOTE_C3,NOTE_G3 };
int durations[] = {
  500, 500, 500, 500, 1000};
 
 
 
//
int playbackCount = 0;//autoplay selection count
int selectionCount= 0;//player selection count
 
int currentLevel = 0;//current game level
 
boolean watchMode = true; //Simon's turn, false means it is the players turn 
 
//store which switch is currently active?
int pressAry[] = {
  0,0,0,0};
 
//Storing the squence that gets randomly generated, Num in brackets states how long sequence is [#]
int sequenceAry[7];
int sequenceAryLegnth = sizeof(sequenceAry) / sizeof(int);
 
void setup()
{
  pinMode(ledWhite, OUTPUT);
  pinMode(ledGreen, OUTPUT);
  pinMode(ledRed, OUTPUT);     
  pinMode(ledYellow, OUTPUT);
  pinMode(switchWhite, INPUT);
  pinMode(switchGreen, INPUT);
  pinMode(switchRed, INPUT);     
  pinMode(switchYellow, INPUT);
  pinMode(transistorPin, OUTPUT);
 
  randomSeed(analogRead(0));//Add this so sequence is truely random
  audioFeedback.begin(speakerPin);
  createRandomSequence();
}
 
void loop()
{
  /************
   *  Check to see if simon/player mode
   *************/
  if(watchMode == true){
   /************
   *  SIMON SEZ: leds automatically blink in random sequence
   *************/
    //have you won?
    if(playbackCount <= sequenceAryLegnth){
      //has simon finshed showing current sequence?
      if(playbackCount < currentLevel){
        //Blink proper LED from leds array
        int activeLED_index = sequenceAry[playbackCount];
        digitalWrite(leds[activeLED_index], HIGH);
        //Play corrisponding note
        audioFeedback.play(notes[activeLED_index]);
        delay(200);
        digitalWrite(leds[activeLED_index], LOW);
        audioFeedback.stop();
        delay(200);
        playbackCount++;
      }
      else{
        //simon is done, now it is players turn
        watchMode = false;
      }
    }
    else{
       /************
       *  PLAYER WINS!
       *************/
      playerWins();
    }
  }
  else{
 
    //Read States of all Switches
    int whiteState = digitalRead(switchWhite);
    int greenState = digitalRead(switchGreen);
    int redState = digitalRead(switchRed);
    int yellowState = digitalRead(switchYellow);
 
    int statesAry[] = {
      whiteState,greenState,redState,yellowState};
 
    //loop across all 4 switch states
    for(int x=0; x<4; x++){
      int switchState = statesAry[x];
      if(switchState == 1){
        audioFeedback.play(notes[x]);
        digitalWrite(leds[x], HIGH);
        delay(200);
        audioFeedback.stop();
        digitalWrite(leds[x], LOW);
 
        if(pressAry[x]==0){
          if(sequenceAry[selectionCount]==x){
            selectionCount++;
            pressAry[x] = 1;
          }
          else{
            resetGame();
          }
 
        }
 
      }
      else{
        pressAry[x] = 0;
        // turn LED off:
        digitalWrite(leds[x], LOW); 
      }
 
      //Check to see if we could incrament level
      if(selectionCount == currentLevel){
        advanceLevel();
      }
    }
 
  }
 
}
 
 
void createRandomSequence(){
   for(int x=0; x<sequenceAryLegnth; x++){
      sequenceAry[x] = random(0, 4);
   } 
 
}
 
/************
 *  Play winning melody
 *************/
void playerWins(){
  for (int thisNote = 0; thisNote < 5; thisNote ++) {
    // play the next note:
    audioFeedback.play(winNotes[thisNote]);
    // hold the note:
    delay(durations[thisNote]);
    // stop for the next note:
    audioFeedback.stop();
  }
  // hold before repeating:
  delay(3000);
}
 
/************
 *  Incrament player one level
 *************/
void advanceLevel(){
  resetValues();
  currentLevel++;
  delay(200);
} 
 
/************
 *  Player pressed wrong button
 *************/
void resetGame(){
  //DISPATCH HAPTIC FEEDBACK 
  digitalWrite(transistorPin, HIGH);
  delay(1000);
  digitalWrite(transistorPin, LOW);
  delay(1000);
 
  resetValues();
  currentLevel = 0;
  delay(1000);
}
 
/************
 *  Reset all values so simon knows to start from the first LED in the sequenceAry
 *************/
void resetValues(){
  selectionCount = 0;
  playbackCount = 0;
  watchMode = true;
}